Az oktatóanyag elmagyarázza a karakterek számlálását az Excelben. Megtanulja a képleteket, hogy megkapja a teljes karakterszámot egy tartományban, és csak egy adott cellában vagy több cellában számoljon konkrét karaktereket.
Korábbi bemutatónk bemutatta az Excel LEN függvényt, amely lehetővé teszi a teljes számolását. karakter a cellában.
A LEN képlet önmagában is hasznos, de más funkciókkal – például a SUM, SUMPRODUCT és SUBSTITUTE – együttműködve sokkal összetettebb feladatokat képes kezelni. Ebben az oktatóanyagban tovább vizsgáljuk néhány alap- és haladó képletet a karakterek számolásához az Excel-ben.
- Számítson meg egy tartományban lévő összes karaktert
- Számoljon meg egy adott karaktert egy cellában
- Megszámoljon egy adott karaktert egy tartományban
Hogyan számoljuk meg az összes karaktert egy tartományban
több cellában lévő karakterek összes számának megszámlálására kerül sor, az azonnali megoldás, hogy az egyes cellák karakterszámát megkapja, majd összeadja ezeket a számokat:
=LEN(A2)+LEN(A3)+LEN(A4)
Vagy
=SUM(LEN(A2),LEN(A3),LEN(A4))
A fenti képletek jól működhetnek egy kis tartományban. Ha az összes karaktert nagyobb tartományban szeretnénk megszámolni, jobb, ha valami kompaktabbat állítunk elő, például a SUMPRODUCT függvényt, amely megsokszorozza a tömböket és visszaadja a termékek összegét.
Itt az általános Excel képlet egy tartományban lévő karakterek számlálásához:
És a valós képlete hasonló lehet ehhez:
=SUMPRODUCT(LEN(A1:A7))
A tartomány karaktereinek számlálásának másik módja a LEN függvény használata SUM:
Enter segítségével tömb képletté alakíthatja.
Amint a következő képernyőképen bemutatjuk, a SUM képlet ugyanazt a teljes karakterláncot adja vissza:
Hogyan működik ez a tartomány karakterképlet
Ez az egyik legegyszerűbb képlet a karakterek számlálásához az Excelben. A LEN függvény kiszámítja a karakterlánc hosszát az egyes cellákhoz a megadott tartományban, és számtömbként adja vissza őket. Ezután a SUMPRODUCT vagy a SUM összeadja ezeket a számokat, és visszaadja az összes karakterszámot.
A fenti példában egy 7 számból álló tömb összegzi az A1 – A7 cellák húrjainak hosszát:
Hogyan kell számolni meghatározott karakterek a cellában
Néha előfordulhat, hogy a cellában lévő összes karakter megszámlálása helyett csak egy adott betű, szám vagy speciális szimbólum előfordulásait kell számolnia.
számolja meg, hogy egy adott karakter hányszor jelenik meg egy cellában, használja a LEN függvényt a SUBSTITUTE -vel együtt:
A képlet jobb megértése érdekében vegye figyelembe a következő példát.
Tegyük fel, hogy a szállított elemek adatbázisát tartja fenn, ahol minden elemtípusnak megvan a maga egyedi azonosítója. És minden cella több elemet tartalmaz vesszővel, szóközzel vagy bármely más elválasztóval. A feladat az, hogy megszámoljuk, hányszor jelenik meg egy adott egyedi azonosító az egyes cellákban.
Feltételezve, hogy a leszállított tételek listája a B oszlopban található (B2-től kezdődően), és számoljuk az “A” számát “előfordulások esetén a képlet a következő:
=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))
Hogyan működik ez az Excel karakterszámolási képlet
A képlet logikájának megértéséhez bontsuk szét kisebb részekre:
Ennek eredményeként eltávolítja a (z) “számát” “karakterek, ami megegyezik a cellában lévő karakterek előfordulásának teljes számával.
Ahelyett, hogy megadná a képletben megszámolni kívánt karaktert, beírhatja egy cellába, majd hivatkozhat arra a cellára. képletben. Ily módon a felhasználók képesek lesznek megszámolni az adott cellába bevitt bármely más karakter előfordulását anélkül, hogy beavatkoznának a képletbe:
Kis- és nagybetűk nélküli Excel-képlet a cellában lévő egyes karakterek számlálásához
Ha kis- és nagybetűk nélküli karakterek számára van szükség, ágyazza be a FELSŐ függvényt a SUBSTITUTE-be, hogy a megadott karakter nagybetűvé váljon fut a csere. És ne felejtse el megadni a nagybetűs karaktert a képletben.
Például a B2 cellában az „A” és „a” elemek számításához használja ezt a képletet:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))
Egy másik módszer a beágyazott helyettesítő függvények használata:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")
Amint az alábbi képernyőképen látható, mindkét képlet hibátlanul számolja a megadott karakter kis- és nagybetűit:
Bizonyos esetekben , lehet, hogy sok különböző karaktert kell megszámolnia egy táblázatban, de nem biztos, hogy minden egyes alkalommal módosítani szeretné a képletet. Ebben az esetben fészkeljen be egy helyettesítő függvényt a másikba, írja be a megszámlálni kívánt karaktert valamelyik cellába (ebben a példában D1), és alakítsa a cella értékét nagy- és kisbetűvé az UPPER és LOWER függvények használatával:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))
Alternatív megoldásként mind a forráscella, mind a karaktert tartalmazó cellát nagy- vagy kisbetűvé alakíthatja. Például:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))
Ennek a megközelítésnek az az előnye, hogy függetlenül attól, hogy a hivatkozott cellába nagy- vagy kisbetűt írunk-e, a kis- és nagybetűket nem érzékeny karakterszámítási képlet visszaadja a megfelelő számot:
A cellában lévő egyes szövegek vagy alszövegek előfordulásainak száma
Ha meg akarja számolni hányszor jelenik meg egy adott karakterkombináció (pl. bizonyos szöveg vagy alszöveg) egy adott cellában, pl. “A2” vagy “SS”, majd ossza el a fenti képletekkel visszaadott karakterek számát az alfej hosszával .
Kis- és nagybetűk közötti képlet:
=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)
A kis- és nagybetűk közötti képlet:
=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)
Ahol a B2 a teljes szövegláncot tartalmazó cella, a C1 pedig a megszámolni kívánt szöveg (alfej).
A képlet részletes magyarázatához lásd: Hogyan kell megszámolni egy cellában az adott szöveget / szavakat.
Hogyan lehet megszámolni egy adott karaktert ( s) egy tartományban
Most, hogy ismer egy Excel-képletet a cellában lévő karakterek számolásához, érdemes tovább javítani, hogy megtudja, egy adott karakter hányszor jelenik meg egy tartományban. Ehhez felvesszük az Excel LEN képletet, hogy megszámoljuk egy adott karaktert az előző példában tárgyalt cellában, és beletesszük a tömbök kezelésére alkalmas SUMPRODUCT függvénybe:
Ebben a példában a képlet a következő formát ölti:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
És itt van egy másik képlet a karakterek számlálásához az Excel tartományában:
=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
Az első képlethez képest a legkézenfekvőbb különbség a SUM használata a SUMPRODUCT helyett. A másik különbség az, hogy meg kell nyomni a Ctrl + Shift + Enter billentyűkombinációt, mert a SUMPRODUCT-tal ellentétben, amelyet tömbök feldolgozására terveztek, a SUM csak akkor tudja kezelni a tömböket, ha tömbképletben használják őket.
Ha nem akarja kódolni a képletben szereplő karakter, természetesen beírhatja néhány cellába, mondjuk D1-be, és hivatkozhat arra a cellára a karakterszám-képletében:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))
Hogyan működik ez a karakterszámlálási képlet
Amint emlékszel, a SUBSTITUTE függvényt a megadott karakter minden előfordulásának (ebben a példában az “A”) helyére egy üres szöveges karakterlánccal ( “”).
Ezután a SUBSTITUTE által visszaküldött szöveges karakterláncot elküldjük az Excel LEN függvénynek, hogy az A “s nélkül számolja ki a karakterlánc hosszát. Ezután kivonjuk a karakterláncot a szöveges karakterlánc teljes hosszából. Ezeknek a számításoknak az eredménye egy karakterszám-tömb, cellánként egy karakter-számmal.
Végül a SUMPRODUCT összegzi a tömbben lévő számokat, és visszaadja a megadott karakter teljes számát a tartományban.
Kis- és nagybetűk nélküli képlet egy adott tartományban lévő karakterek megszámlálásához
Már tudja, hogy a SUBSTITUTE kis- és nagybetűk függvény, amely Excel-karakterképletünket a karakterek megkülönböztetésére is teszi.
A képlet figyelmen kívül hagyásához kövesse az előző példában bemutatott megközelítéseket: A kis- és nagybetűk közötti képlet a cellában lévő egyes karakterek számlálásához.
Különösen a következők egyikét használhatja: a következő képletek a karakterek megszámolásához egy tartományban, figyelmen kívül hagyva az esetet:
Az alábbi képernyőkép bemutatja az utolsó képletet:
Így számolhat karaktereket az Excelben a LEN használatával funkció.Ha tudni szeretné, hogy az egyes karakterek helyett hogyan kell megszámolni a szavakat, a következő cikkünkben talál néhány hasznos képletet, kérjük, maradjon velünk!
Addig is letölthet egy példát munkafüzetekre, amelyekben karakterek vannak. az ebben az oktatóanyagban tárgyalt képletet, és nézze meg a kapcsolódó források listáját az oldal végén. Köszönöm, hogy elolvastad, és remélem, hogy hamarosan találkozunk!
- Excel LEN függvény – képletek a cellák hosszának, azaz a cellában lévő karakterek számának kiszámításához szóközzel vagy szóköz nélkül.
- Hogyan számoljuk meg a szavakat az Excelben – a kis- és nagybetűk és a kis- és nagybetűk közötti képletek a cellában vagy cellatartományban található összes vagy konkrét szavak számlálásához.
- COUNT és COUNTA függvények – cellák számlálása számokkal és nem üres cellákkal.
- COUNTIF függvény – képletek a cellák feltételes számlálására az Excelben.
- COUNTIFS függvény – több kritériummal rendelkező cellák számlálása.
