El tutorial explica cómo contar caracteres en Excel. Aprenderá las fórmulas para obtener el recuento total de caracteres en un rango y contar solo caracteres específicos en una celda o en varias celdas.
Nuestro tutorial anterior introdujo la función Excel LEN, que permite contar el número total de caracteres en una celda.
La fórmula LEN es útil por sí sola, pero en combinación con otras funciones como SUM, SUMPRODUCT y SUBSTITUTE, puede manejar tareas mucho más complejas. Más adelante en este tutorial, veremos más de cerca algunas fórmulas básicas y avanzadas para contar caracteres en Excel.
- Contar un número total de caracteres en un rango
- Contar caracteres específicos en una celda
- Contar caracteres específicos en un rango
Cómo contar todos los caracteres en un rango
Cuando llega a contar un número total de caracteres en varias celdas, una solución inmediata que me viene a la mente es obtener el recuento de caracteres para cada celda y luego sumar esos números:
=LEN(A2)+LEN(A3)+LEN(A4)
O
=SUM(LEN(A2),LEN(A3),LEN(A4))
Las fórmulas anteriores pueden funcionar bien para un rango pequeño. Para contar el total de caracteres en un rango mayor, será mejor que creemos algo más compacto, por ejemplo, la función SUMPRODUCT, que multiplica las matrices y devuelve la suma de los productos.
Aquí está el Excel genérico fórmula para contar caracteres en un rango:
Y su fórmula de la vida real puede verse similar a esto:
=SUMPRODUCT(LEN(A1:A7))
Otra forma de contar caracteres en un rango es usar la función LEN en combinación con SUM:
=SUM(LEN(A1:A7))
A diferencia de SUMPRODUCT, la función SUM no calcula matrices de forma predeterminada, y debe presionar Ctrl + Shift + Ingrese para convertirlo en una fórmula de matriz.
Como se muestra en la siguiente captura de pantalla, la fórmula SUM devuelve el mismo recuento total de caracteres:
Cómo funciona esta fórmula de recuento de caracteres de rango
Esta es una de las fórmulas más sencillas para contar caracteres en Excel. La función LEN calcula la longitud de la cadena para cada celda en el rango especificado y las devuelve como una matriz de números. Y luego, SUMPRODUCT o SUM suma esos números y devuelve el recuento total de caracteres.
En el ejemplo anterior, se suma una matriz de 7 números que representan las longitudes de cadenas en las celdas A1 a A7:
Cómo contar caracteres específicos en una celda
A veces, en lugar de contar todos los caracteres dentro de una celda, es posible que deba contar solo las apariciones de una letra, número o símbolo especial específico.
Para cuente el número de veces que un carácter determinado aparece en una celda, use la función LEN junto con SUBSTITUTE:
Para comprender mejor la fórmula, considere el siguiente ejemplo.
Suponga que mantiene una base de datos de artículos entregados, donde cada tipo de artículo tiene su propio identificador único. Y cada celda contiene varios elementos separados por coma, espacio o cualquier otro delimitador. La tarea es contar cuántas veces aparece un identificador único dado en cada celda.
Suponiendo que la lista de artículos entregados está en la columna B (comenzando en B2), y estamos contando el número de «A «ocurrencias, la fórmula es la siguiente:
=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))
Cómo funciona esta fórmula de recuento de caracteres de Excel
Para comprender la lógica de la fórmula, dividámosla en partes más pequeñas:
Como resultado, obtiene el recuento de «eliminado «caracteres, que equivale al número total de apariciones de ese carácter en la celda.
En lugar de especificar el carácter que desea contar en una fórmula, puede escribirlo en alguna celda y luego hacer referencia a esa celda en una fórmula. De esta manera, sus usuarios podrán contar las apariciones de cualquier otro carácter que ingresen en esa celda sin alterar su fórmula:
Fórmula de Excel que no distingue entre mayúsculas y minúsculas para contar caracteres específicos en una celda
Si necesita un recuento de caracteres que no distingue entre mayúsculas y minúsculas, incruste la función SUPERIOR dentro de SUBSTITUTO para convertir el carácter especificado a mayúscula antes ejecutar la sustitución. Y asegúrese de ingresar el carácter en mayúsculas en la fórmula.
Por ejemplo, para contar los elementos «A» y «a» en la celda B2, use esta fórmula:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))
Otra forma es usar funciones sustitutas anidadas:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")
Como puede ver en la siguiente captura de pantalla, ambas fórmulas cuentan sin problemas las apariciones en mayúsculas y minúsculas del carácter especificado:
En algunos casos , es posible que deba contar muchos caracteres diferentes en una tabla, pero es posible que no desee modificar la fórmula cada vez. En este caso, anide una función de sustitución dentro de otra, escriba el carácter que desea contar en alguna celda (D1 en este ejemplo) y convierta el valor de esa celda en mayúsculas y minúsculas utilizando las funciones UPPER y LOWER:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))
Alternativamente, convierta tanto la celda de origen como la celda que contiene el carácter a mayúsculas o minúsculas. Por ejemplo:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))
La ventaja de este enfoque es que independientemente de si se ingresa el carácter en mayúsculas o minúsculas en la celda referenciada, su fórmula de recuento de caracteres que no distingue entre mayúsculas y minúsculas devolverá el recuento correcto:
Cuente las apariciones de cierto texto o subcadena en una celda
Si desea contar cuántas veces aparece una combinación específica de caracteres (es decir, cierto texto o subcadena) en una celda determinada, p. ej., «A2» o «SS», luego divida el número de caracteres devueltos por las fórmulas anteriores por la longitud de la subcadena .
Fórmula que distingue entre mayúsculas y minúsculas:
=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)
Fórmula que distingue entre mayúsculas y minúsculas:
=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)
Donde B2 es la celda que contiene la cadena de texto completa y C1 es el texto (subcadena) que desea contar.
Para obtener una explicación detallada de la fórmula, consulte Cómo contar texto / palabras específicos en una celda.
Cómo contar caracteres específicos ( s) en un rango
Ahora que conoce una fórmula de Excel para contar caracteres en una celda, es posible que desee mejorarla más para saber cuántas veces aparece un determinado carácter en un rango. Para esto, tomaremos la fórmula de Excel LEN para contar un carácter específico en una celda discutida en el ejemplo anterior, y la colocaremos dentro de la función SUMPRODUCT que puede manejar matrices:
En este ejemplo, la fórmula toma la siguiente forma:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
Y aquí hay otra fórmula para contar caracteres en el rango de Excel:
=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
En comparación con la primera fórmula, la diferencia más obvia es usar SUM en lugar de SUMPRODUCT. Otra diferencia es que requiere presionar Ctrl + Shift + Enter porque a diferencia de SUMPRODUCT, que está diseñado para procesar matrices, SUM puede manejar matrices solo cuando se usa en una fórmula de matriz.
Si no desea codificar el carácter en la fórmula, por supuesto, puede escribirlo en alguna celda, digamos D1, y hacer referencia a esa celda en su fórmula de recuento de caracteres:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))
Cómo funciona esta fórmula de conteo de caracteres
Como recordará, la función SUSTITUIR se usa para reemplazar todas las ocurrencias del carácter especificado («A» en este ejemplo) con una cadena de texto vacía ( «»).
Luego, proporcionamos la cadena de texto devuelta por SUBSTITUTE a la función LEN de Excel para que calcule la longitud de la cadena sin A «s. Y luego, restamos ese recuento de caracteres de la longitud total de la cadena de texto. El resultado de estos cálculos es una matriz de recuentos de caracteres, con un recuento de caracteres por celda.
Finalmente, SUMPRODUCT suma los números en la matriz y devuelve el recuento total del carácter especificado en el rango.
Una fórmula que no distingue entre mayúsculas y minúsculas para contar caracteres específicos en un rango
Ya sabe que SUSTITUIR es una función que distingue entre mayúsculas y minúsculas, lo que hace que nuestra fórmula de Excel para el recuento de caracteres también distinga entre mayúsculas y minúsculas.
Para hacer que la fórmula ignore las mayúsculas y minúsculas, siga los enfoques demostrados en el ejemplo anterior: Fórmula que no distingue entre mayúsculas y minúsculas para contar caracteres específicos en una celda.
En particular, puede usar uno de las siguientes fórmulas para contar caracteres específicos en un rango ignorando el caso:
La siguiente captura de pantalla muestra la última fórmula en acción:
Así es como puede contar caracteres en Excel usando el LEN función.Si desea saber cómo contar palabras en lugar de caracteres individuales, encontrará algunas fórmulas útiles en nuestro próximo artículo. ¡Estén atentos!
Mientras tanto, puede descargar libros de trabajo de muestra con recuento de caracteres fórmula discutida en este tutorial, y consulte una lista de recursos relacionados al final de la página. ¡Gracias por leer y espero verte pronto!
- Función Excel LEN: fórmulas para calcular la longitud de una celda, es decir, el número total de caracteres en una celda, con o sin espacios.
- Cómo contar palabras en Excel: fórmulas que distinguen entre mayúsculas y minúsculas y que no distinguen entre mayúsculas y minúsculas para contar palabras totales o específicas en una celda o rango de celdas.
- Funciones COUNT y COUNTA: contar celdas con números y celdas que no están en blanco.
- Función COUNTIF: fórmulas para contar celdas condicionalmente en Excel.
- Función COUNTIFS: cuenta celdas con más de un criterio.
