Självstudien förklarar hur man räknar tecken i Excel. Du lär dig formlerna för att få det totala antalet tecken i ett intervall och bara räkna specifika tecken i en cell eller i flera celler.

Vår tidigare handledning introducerade Excel LEN-funktionen, som gör det möjligt att räkna det totala antalet av tecken i en cell.

LEN-formeln är användbar ensam, men i samband med andra funktioner som SUM, SUMPRODUCT och SUBSTITUTE kan den hantera mycket mer komplexa uppgifter. Längre fram i denna handledning kommer vi att titta närmare på några grundläggande och avancerade formler för att räkna tecken i Excel.

• Räkna totalt antal tecken i ett intervall
• Räkna specifika tecken i en cell
• Räkna specifika tecken i ett område

Hur man räknar alla tecken i ett intervall

När det kommer att räkna ett totalt antal tecken i flera celler, en omedelbar lösning som kommer att tänka på är att få teckenantalet för varje cell och sedan lägga till dessa siffror:

=LEN(A2)+LEN(A3)+LEN(A4)

Eller

=SUM(LEN(A2),LEN(A3),LEN(A4))

Ovanstående formler kan fungera bra för ett litet intervall. För att räkna totalt antal tecken i ett större intervall, skulle vi bättre komma med något mer kompakt, t.ex. SUMPRODUCT-funktionen, som multiplicerar matriserna och returnerar summan av produkterna.

Här är det generiska Excel formel för att räkna tecken i ett intervall:

Och din verkliga formel kan se ut som den här:

=SUMPRODUCT(LEN(A1:A7))

Ett annat sätt att räkna tecken i ett intervall är att använda LEN-funktionen i kombination med SUMMA:

=SUM(LEN(A1:A7))

Till skillnad från SUMPRODUCT beräknar SUM-funktionen inte matriser som standard och du måste trycka på Ctrl + Skift + Enter för att förvandla den till en matrisformel.

Som visas i följande skärmdump returnerar SUM-formeln samma totala antal tecken:

Så här fungerar denna form för räkneteckenräkning

Detta är en av de enklaste formlerna att räkna tecken i Excel. LEN-funktionen beräknar stränglängden för varje cell i det angivna intervallet och returnerar dem som en rad med siffror. Och sedan lägger SUMPRODUCT eller SUM till dessa siffror och returnerar det totala antalet tecken.

I exemplet ovan summeras en matris med 7 nummer som representerar längden på strängarna i cellerna A1 till A7:

Hur man räknar specifika tecken i en cell

Ibland, istället för att räkna alla tecken i en cell, kan du behöva bara räkna förekomsten av en viss bokstav, nummer eller specialsymbol.

Till räkna antalet gånger ett visst tecken visas i en cell, använd LEN-funktionen tillsammans med SUBSTITUTE:

För att bättre förstå formeln, överväga följande exempel.

Antag att du underhåller en databas med levererade artiklar, där varje artikeltyp har sin egen unika identifierare. Och varje cell innehåller flera objekt åtskilda av komma, mellanslag eller någon annan avgränsare. Uppgiften är att räkna hur många gånger en given unik identifierare visas i varje cell.

Förutsatt att listan över levererade artiklar finns i kolumn B (börjar i B2) och vi räknar antalet ”A ”händelser, formeln är som följer:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Så här fungerar Excel-räkneformeln

För att förstå formelns logik, låt oss dela upp den i mindre delar:

Som ett resultat får du räkningen av ”borttagen ”tecken, vilket motsvarar ett totalt antal av den karaktären som förekommer i cellen.

I stället för att ange det tecken du vill räkna i en formel kan du skriva det i någon cell och sedan referera till den cellen i en formel. På detta sätt kommer dina användare att kunna räkna förekomster av alla andra tecken som de matar in i den cellen utan att manipulera med din formel:

Skiftlägeskänslig Excel-formel för att räkna specifika tecken i en cell

Om du behöver ett skiftlägeskänsligt teckenantal, bädda in UPPER-funktionen i SUBSTITUTE för att konvertera det angivna tecknet till versaler före kör utbytet. Och var noga med att ange versaler i formeln.

Till exempel, för att räkna ”A” och ”a” objekt i cell B2, använd denna formel:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

Ett annat sätt är att använda kapslade ersättningsfunktioner:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Som du kan se i skärmdumpen nedan, räknar båda formlerna med stora och små bokstäver av det angivna tecknet:

I vissa fall , du kan behöva räkna många olika tecken i en tabell, men du kanske inte vill ändra formeln varje gång. I det här fallet häckar du en ersättningsfunktion i en annan, skriver tecknet du vill räkna i någon cell (D1 i det här exemplet) och konverterar cellens värde till versaler och små bokstäver med hjälp av UPPER- och LOWER-funktionerna:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Alternativt kan du konvertera både källcellen och cellen som innehåller tecknet antingen till versaler eller små bokstäver. Till exempel:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Fördelen med detta tillvägagångssätt är att oavsett om versaler eller små bokstäver matas in i den refererade cellen, så är din skiftlägeskänsliga formel för teckenräkning kommer att returnera rätt antal:

Räkna förekomster av viss text eller delsträng i en cell

Om du vill räkna hur många gånger en specifik kombination av tecken (dvs. viss text eller delsträng) visas i en given cell, t.ex. ”A2” eller ”SS”, dividera sedan antalet tecken som returneras med formlerna ovan med längden på understrängen .

Skiftlägeskänslig formel:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Skiftlägeskänslig formel:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Där B2 är cellen som innehåller hela textsträngen och C1 är den text (substring) du vill räkna.

För detaljerad förklaring av formeln, se Hur man räknar specifik text / ord i en cell.

Hur man räknar specifikt tecken ( s) i ett intervall

Nu när du känner till en Excel-formel för att räkna tecken i en cell kanske du vill förbättra den ytterligare för att ta reda på hur många gånger ett visst tecken visas i ett intervall. För detta kommer vi att ta Excel LEN-formeln för att räkna en specifik char i en cell som diskuterades i föregående exempel och placera den i SUMPRODUCT-funktionen som kan hantera matriser:

I detta exempel har formeln följande form:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Och här är en annan formel för att räkna tecken i Excel: s intervall:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Jämfört med den första formeln är den mest uppenbara skillnaden att använda SUM istället för SUMPRODUCT. En annan skillnad är att det kräver att du trycker på Ctrl + Shift + Enter eftersom till skillnad från SUMPRODUCT, som är utformad för att bearbeta matriser, kan SUM bara hantera matriser när de används i en matrisformel.

Om du inte vill ha hårdkod karaktären i formeln, du kan naturligtvis skriva den i någon cell, säg D1, och referera till den cellen i din teckenräkningsformel:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Så här fungerar denna räkneformel

Som du kanske kommer ihåg används SUBSTITUTE-funktionen för att ersätta alla förekomster av det angivna tecknet (”A” i detta exempel) med en tom textsträng ( ””).

Sedan levererar vi textsträngen som returneras av SUBSTITUTE till Excel LEN-funktionen så att den beräknar stränglängden utan A ”s. Och sedan subtraherar vi det teckenantalet från textsträngens totala längd. Resultatet av dessa beräkningar är en matris av teckenräkningar med ett teckenantal per cell.

Slutligen summerar SUMPRODUCT siffrorna i matrisen och returnerar det totala antalet för det angivna tecknet i intervallet.

En skiftlägeskänslig formel för att räkna specifika tecken i ett område

Du vet redan att SUBSTITUTE är en skiftlägeskänslig funktion, vilket också gör vår Excel-formel för teckenräkning skiftlägeskänslig.

För att få formeln att ignorera skiftläge, följ metoderna som visas i föregående exempel: Skiftlägeskänslig formel för att räkna specifika tecken i en cell.

I synnerhet kan du använda en av följande formler för att räkna specifika tecken i ett intervall som ignorerar fall:

Nedanstående skärmdump visar den sista formeln i aktion:

Så här kan du räkna tecken i Excel med LEN fungera.Om du vill veta hur man räknar ord snarare än enskilda tecken, hittar du några användbara formler i vår nästa artikel. Håll dig uppdaterad!

Under tiden kan du ladda ner ett exempel på arbetsböcker med teckenantal. formel som diskuteras i denna handledning och kolla in en lista med relaterade resurser i slutet av sidan. Jag tackar för att du läste och hoppas att vi ses snart!

• Excel LEN-funktion – formler för att beräkna längden på en cell, dvs det totala antalet tecken i en cell, med eller utan mellanslag.
• Hur man räknar ord i Excel – skiftlägeskänsliga och skiftlägeskänsliga formler för att räkna totala eller specifika ord i en cell eller ett cellintervall.
• RÄKNING- och COUNTA-funktioner – räkna celler med siffror och icke-tomma celler.
• COUNTIF-funktion – formler för att villkorligt räkna celler i Excel.
• COUNTIFS-funktion – räkna celler med mer än ett kriterium.